home *** CD-ROM | disk | FTP | other *** search
/ BBS Toolkit / BBS Toolkit.iso / windows / mrun211.zip / MRUN211E.WAS < prev    next >
Text File  |  1993-05-01  |  20KB  |  745 lines
  1. ;MailRun v2.11:  Part E, addulfile
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This file contains routines related to adding a "Upload File"
  9. * item to a mailrun.  It puts up the Upload Files dialog box,
  10. * which displays the contents of the available files index (the
  11. * *.udx file for the mailrun).  When a file is selected from the 
  12. * list, a detailed description is displayed from the *.ubf file 
  13. * for the mailrun).
  14. * 
  15. **************************************************************************
  16. **************************************************************************
  17. #endcomment
  18.  
  19. #define MRUN211E
  20. #define MRUN211DE
  21.  
  22. #include "mrun211.h"
  23.  
  24. string DXFileTabs, OldUDX, OldUBF, MRunUDX, MRunUBF, LastChoice
  25. string UploadDir, DownloadDir, BBSChoice
  26. integer InULDir, ULSortField
  27.  
  28. #comment
  29. *********************************************************************
  30. * 
  31. * MAIN()
  32. * 
  33. * Calls checkchild(), updateudx(), interfaceon(), getnewdesc(),
  34. * getulfiles(), checkchanged(), getlastitem(), gettaskstring(), 
  35. * clearfiledesc(), makebbslist(), ulfilebox(), insertulfile(), 
  36. * delulfile(), menudim(), makefullname(), sortidx(), checkfile()
  37. * 
  38. * Adds a SendFile item to the mailrun.  An feditbox is
  39. * used to display the file description in order to take
  40. * advantage of wordwrap.  The flistbox displays the
  41. * contents of MAILRUN.UDX, which contains information on
  42. * any file downloaded by MailRun, plus additional files
  43. * found in the upload directory.  A file description must
  44. * be at least 6 characters, but may be as long as needed.
  45. * 
  46. *********************************************************************
  47. #endcomment
  48.  
  49. proc main
  50. string FullFileName, char, temp
  51. integer dialogstatus
  52. integer j, InUDX
  53.     menudim()
  54.     checkchild()
  55.     findfirst MailRun
  56.     MailRunTrunc = $FILENAME
  57.     DXFileTabs = "58,92,130,305,315,319,322,325,328"
  58.     profilerd MailRun "MailRun" "UploadDir" UploadDir
  59.     profilerd MailRun "MailRun" "DownloadDir" DownloadDir
  60.     profilerd MailRun "MailRun" "ULSortField" ULSortField
  61.     strextract BBSChoice TaskItem "`t" 3
  62.     strextract char TaskItem "`t" 4
  63.     atoi char j
  64.     FileDesc = makefullname(TempDir, "DESC.TMP")
  65.     OldUDX = makefullname(TempDir, "OLDUDX.TMP")
  66.     OldUBF = makefullname(TempDir, "OLDUBF.TMP")
  67.     MRunUDX = makefullname(MailRunDir, "MAILRUN.UDX")
  68.     MRunUBF = makefullname(MailRunDir, "MAILRUN.UBF")
  69.     if isfile FileDesc
  70.         delfile FileDesc
  71.     endif
  72.     if not (checkfile(MRunUDX) && checkfile(MRUNUBF))
  73.         getulfiles()
  74.     endif
  75.     LastChoice = ""
  76.     FLAGS &= UNCHANGED
  77.     interfaceon()
  78.     makebbslist()
  79.     ulfilebox()
  80.     dialogstatus = $DIALOG
  81.     while dialogstatus != 1
  82.         switch dialogstatus
  83.             case 10
  84.                 ;User selected "Add"
  85.                 insertulfile(&j)
  86.                 TaskItem = gettaskstring(BBSChoice, j)
  87.             endcase
  88.             case 11
  89.                 ;User selected "Save"
  90.                 if FLAGS & CHANGED
  91.                     updateudx()
  92.                     FLAGS &= UNCHANGED
  93.                     updatedlg -1
  94.                 endif
  95.             endcase
  96.             case 12
  97.                 ;User selected "Delete"
  98.                 delulfile()
  99.             endcase
  100.             case 13
  101.                 ;User selected "Refresh"
  102.                 statmsg "Refreshing Uploads List from Upload Directory..."
  103.                 getulfiles()
  104.                 updatedlg -1
  105.                 statmsg ""
  106.             endcase
  107.             case 50
  108.                 ;User selected a sort radiobutton
  109.                 profilewr MailRun "MailRun" "ULSortField" ULSortField
  110.                 sortidx(MRunUDX, ULSortField)
  111.                 updatedlg 16
  112.             endcase
  113.             case 130
  114.                 ;User selected a file from the listbox
  115.                 if checkchanged()
  116.                     getnewdesc()
  117.                     updatedlg 137
  118.                 else
  119.                     FileChoice = LastChoice
  120.                     updatedlg 16
  121.                 endif
  122.             endcase
  123.             case 170
  124.                 ;User changed BBSs with the combobox
  125.                 j = getlastitem(BBSChoice)
  126.                 TaskItem = gettaskstring(BBSChoice, j)
  127.             endcase
  128.             case 230
  129.                 ;User entered a name in the File Name box
  130.                 FullFileName = makefullname(UploadDir, FileName)
  131.                 if isfile FullFileName
  132.                     InULDir = 1
  133.                 else
  134.                     InULDir = 0
  135.                 endif
  136.                 interfaceoff()
  137.                 openfile(MRunUDXFile, MRunUDX, _READWRITE, _TEXT)
  138.                 InUDX = checkudx(FileName)
  139.                 if InUDX
  140.                     fseek MRunUDXFile -100 1
  141.                     fgets MRunUDXFile FileChoice
  142.                     fgets MRunUDXFile FileChoice
  143.                     strextract temp FileChoice "`t" 0
  144.                     while not strcmpi temp FileName
  145.                         fgets MRunUDXFile FileChoice
  146.                         strextract temp FileChoice "`t" 0
  147.                     endwhile
  148.                 endif
  149.                 fclose MRunUDXFile
  150.                 interfaceon()
  151.                 if InUDX
  152.                     makedesc(MRunUBF)
  153.                 else                
  154.                     clearfiledesc()
  155.                 endif
  156.                 updatedlg -1
  157.             endcase
  158.             case 250
  159.                 ;User entered a file description
  160.                 if !(FLAGS & CHANGED)
  161.                     FLAGS |= CHANGED
  162.                 endif
  163.             endcase
  164.         endswitch
  165.         dialogstatus = $DIALOG
  166.     endwhile
  167. endproc
  168.  
  169.  
  170. #comment
  171. *********************************************************************
  172. * 
  173. * INSERTULFILE()
  174. * 
  175. * Called by main()
  176. * 
  177. * Calls openfile(), updateudx(), insertitem(),
  178. * interfaceon(), interfaceoff(), makefullname(), checkudx(),
  179. * clearfiledesc(), shortdesc()
  180. * 
  181. * Adds a SendFile item to the *.MRN file and the task list.
  182. * 
  183. *********************************************************************
  184. #endcomment
  185.  
  186. proc insertulfile
  187. intparm j
  188. string ULDescString, ULFileString, FullFileName
  189. string ULFileSpec, StatString, CopyboxMsg
  190. integer ULDescLength, Perm, Response, InUDX
  191.     interfaceoff()
  192.     if NULLSTR FileName
  193.         ;User hasn't selected a file
  194.         usermsg "You must select a file first."
  195.         return
  196.     endif
  197.     if InULDir == 0
  198.         strupr FileName
  199.         strfmt CopyBoxMsg \
  200.             "%s is not in the Upload Directory.`r`nCopy it now?" \
  201.             FileName
  202.         strlwr FileName
  203.         sdlgmsgbox "MailRun Message" CopyBoxMsg QUESTION \
  204.             OKCANCEL Response 1
  205.         switch Response
  206.             case 1
  207.                 ;User selected "OK"
  208.                 ULFileSpec = makefullname(DownloadDir, FileName)
  209.                 dir ULFileSpec FullFileName
  210.                 if NULLSTR FullFileName
  211.                     return
  212.                 endif
  213.                 if not isfile FullFileName
  214.                     sdlgmsgbox "MailRun Message" "No such file!" \
  215.                         EXCLAMATION OK Response 1
  216.                     return
  217.                 endif
  218.                 copyfile FullFileName UploadDir
  219.                 if not strcmpi ULFileSpec FullFileName
  220.                     ;if the user chose a file other than the one specified
  221.                     ;get the name of the file
  222.                     findfirst FullFileName
  223.                     FileName = $FILENAME
  224.                     strlwr FileName
  225.                     ;determine whether it is already in the uploads database
  226.                     openfile(MRunUDXFile, MRunUDX, _READWRITE, _TEXT)
  227.                     InUDX = checkudx(FileName)
  228.                     fclose MRunUDXFile
  229.                     if InUDX == 0
  230.                         ;if it isn't in the uploads database, put it there
  231.                         clearfiledesc()
  232.                         FLAGS |= CHANGED
  233.                         updateudx()
  234.                     endif
  235.                 endif
  236.                 InULDir = 1
  237.                 updatedlg -1
  238.             endcase
  239.             case 2
  240.                 ;User selected "Cancel"
  241.                 return
  242.             endcase
  243.         endswitch
  244.     endif
  245.     ;No description may be less than 6 characters
  246.     openfile(FileDescFile, FileDesc, _READWRITE, _NORMAL)
  247.     fread FileDescFile ULDescString 65 ULDescLength
  248.     fclose FileDescFile
  249.     if ULDescLength < 6
  250.         usermsg "Please enter a longer description."
  251.     elseif shortdesc(ULDescString, ULDescLength)
  252.         ;If everything is OK...
  253.         if FLAGS & CHANGED
  254.             ;Add the new description to the database
  255.             updateudx()
  256.             FLAGS &= UNCHANGED
  257.             updatedlg 16
  258.         endif
  259.         Perm = 2 - PermRadio
  260.         strupr FileName
  261.         strfmt ULFileString \
  262.             "1,%d,SendFile,%s,%s" Perm FileName Conf
  263.         strfmt StatString \
  264.             "Added to %s:  `"Upload %s to Conference %s`"" \
  265.             BBSChoice FileName Conf
  266.         j++
  267.         insertitem(BBSChoice, j, ULFileString)
  268.         strlwr FileName
  269.         statmsg StatString
  270.     endif
  271.     interfaceon()
  272. endproc
  273.  
  274.  
  275. #comment
  276. *********************************************************************
  277. * 
  278. * SHORTDESC()
  279. * 
  280. * Called by insertulfile()
  281. * 
  282. * Calls findstring()
  283. * 
  284. * If the current BBS type is WildCat! or RBBS, limits the 
  285. * upload description length to 60 or 45 characters,
  286. * respectively.  Gives user an opportunity to enter a new 
  287. * description if the current one is too long.
  288. * 
  289. *********************************************************************
  290. #endcomment
  291.  
  292. func shortdesc : integer
  293. strparm ULDescString
  294. intparm ULDescLength
  295. string ULMsg, TypeName
  296. integer Response, MaxLength
  297.     profilerd MailRun BBSChoice "BBSType" BBSType
  298.     if (findstring(BBSType, "WildCat") && (ULDescLength > 60)) || \
  299.         (findstring(BBSType, "RBBS") && (ULDescLength > 45))
  300.         if findstring(BBSType, "WildCat")
  301.             substr ULDescString ULDescString 0 60
  302.             MaxLength = 60
  303.             TypeName = "WildCat!"
  304.         else
  305.             substr ULDescString UlDescString 0 45
  306.             MaxLength = 45
  307.             TypeName = "RBBS"
  308.         endif
  309.         strfmt ULMsg "A %s file description has a maximum length \
  310. of %d characters.  The description for %s will be truncated to read:\
  311. `r`n`r`n%s`r`n`r`nDo you wish to continue?" \
  312.             TypeName MaxLength FileName ULDescString
  313.         sdlgmsgbox "MailRun Message" ULMsg QUESTION YESNO Response 2
  314.         switch Response
  315.             case 6
  316.                 return 1
  317.             endcase
  318.             case 7
  319.                 return 0
  320.             endcase
  321.         endswitch
  322.     else
  323.         return 1
  324.     endif
  325. endfunc
  326.  
  327.  
  328. #comment
  329. *********************************************************************
  330. * 
  331. * DELULFILE()
  332. * 
  333. * Called by main()
  334. * 
  335. * Calls killfile(), makefullname()
  336. * 
  337. * Deletes a file from the upload database index.
  338. * 
  339. *********************************************************************
  340. #endcomment
  341.  
  342. proc delulfile
  343. string DelBoxMsg, FullFileName
  344. integer Response
  345.     if not NULLSTR FileName
  346.         if InULDir == 1
  347.             ;If the selected file is in the upload directory
  348.             strfmt DelBoxMsg "Delete file %s as well?" FileName
  349.             sdlgmsgbox "MailRun Message" DelBoxMsg QUESTION \
  350.                 YESNOCANCEL Response 1
  351.             switch Response
  352.                 case 2
  353.                     ;User selected "Cancel"
  354.                     return
  355.                 endcase
  356.                 case 6
  357.                     ;User selected "Yes"
  358.                     FullFileName = makefullname(UploadDir, FileName)
  359.                     delfile FullFileName
  360.                 case 7
  361.                     ;User selected "No"
  362.                     killfile()
  363.                 endcase
  364.             endswitch
  365.         else
  366.             killfile()
  367.         endif
  368.         FLAGS &= UNCHANGED
  369.         updatedlg -1
  370.     endif
  371. endproc
  372.  
  373.  
  374. #comment
  375. *********************************************************************
  376. * 
  377. * KILLFILE()
  378. * 
  379. * Called by delulfile()
  380. * 
  381. * Calls openfile(), clearfiledesc(), getnewdesc()
  382. * 
  383. * Deletes a file from the upload database index.
  384. * 
  385. *********************************************************************
  386. #endcomment
  387.  
  388. proc killfile
  389. string UDXString, UDXFile, temp
  390.     ;Copy all but the new description to the new UDX file
  391.     copyfile MRunUDX OldUDX
  392.     openfile(OldUDXFile, OldUDX, _READWRITE, _TEXT)
  393.     openfile(MRunUDXFile, MRunUDX, _CREATE, _TEXT)
  394.     fgets OldUDXFile UDXString
  395.     while not feof OldUDXFile
  396.         ;Read lines until the end of file or the current file
  397.         strextract UDXFile UDXString "`t" 0
  398.         if strcmpi UDXFile FileName
  399.             exitwhile
  400.         endif
  401.         fputs MRunUDXFile UDXString
  402.         fgets OldUDXFile UDXString
  403.     endwhile
  404.     fgets OldUDXFile UDXString
  405.     ;get the new listbox selection
  406.     FileChoice = UDXString
  407.     while not feof OldUDXFile
  408.         fputs MRunUDXFile UDXString
  409.         fgets OldUDXFile UDXString
  410.     endwhile
  411.     if NULLSTR FileChoice
  412.         ;if the deleted line was the last in the file
  413.         ;back up one line and read it
  414.         fseek MRunUDXFile -100 2
  415.         fgets MRunUDXFile temp
  416.         while not NULLSTR temp
  417.             FileChoice = temp
  418.             fgets MRunUDXFile temp
  419.         endwhile
  420.     endif
  421.     if not NULLSTR FileChoice
  422.         getnewdesc()
  423.     else
  424.         FileName = ""
  425.         clearfiledesc()
  426.     endif
  427.     fclose OldUDXFile
  428.     fclose MRunUDXFile
  429.     delfile OldUDX
  430. endproc
  431.  
  432.  
  433. #comment
  434. *********************************************************************
  435. * 
  436. * GETNEWDESC()
  437. * 
  438. * Called by main(), killfile()
  439. * 
  440. * Calls makedesc(), makefullname()
  441. * 
  442. * Gets the file name and description from the index entry
  443. * and determines whether the file is in the upload directory.
  444. * 
  445. *********************************************************************
  446. #endcomment
  447.  
  448. proc getnewdesc
  449. string FullFileName
  450.     LastChoice = FileChoice
  451.     strextract FileName FileChoice "`t" 0
  452.     FullFileName = makefullname(UploadDir, FileName)
  453.     if isfile FullFileName
  454.         InULDir = 1
  455.     else
  456.         InULDir = 0
  457.     endif
  458.     makedesc(MRunUBF)
  459. endproc
  460.  
  461.  
  462. #comment
  463. *********************************************************************
  464. * 
  465. * GETULFILES()
  466. * 
  467. * Called by main()
  468. * 
  469. * Calls openfile(), checkudx(), checkfile(), sortidx(),
  470. * interfaceon(), interfaceoff(), makefullname()
  471. * 
  472. * Updates the Upload directory file description database.
  473. * 
  474. *********************************************************************
  475. #endcomment
  476.  
  477. proc getulfiles
  478. string FileSize, FileDate, FDesc, DescBegin, DescLength, UDXString
  479. string ULFileFull, ULFileTrunc, FullFileName
  480. long FS, DB, DL, NDB, counter
  481. integer char
  482. integer InUDX
  483.     interfaceoff()
  484.     if checkfile(MRunUDX) && checkfile(MRunUBF)
  485.         copyfile MRunUDX OldUDX
  486.         copyfile MRunUBF OldUBF
  487.         openfile(OldUDXFile, OldUDX, _READWRITE, _TEXT)
  488.         openfile(OldUBFFile, OldUBF, _READWRITE, _NORMAL)
  489.     else
  490.         openfile(OldUDXFile, OldUDX, _CREATE, _TEXT)
  491.         openfile(OldUBFFile, OldUBF, _CREATE, _NORMAL)
  492.     endif
  493.     openfile(MRunUDXFile, MRunUDX, _CREATE, _TEXT)
  494.     openfile(MRunUBFFile, MRunUBF, _CREATE, _NORMAL)
  495.     fgets OldUDXFile UDXString
  496.     while not feof OldUDXFile
  497.         ;loop through the old .UDX file
  498.         ;extract all fields
  499.         strextract ULFileTrunc UDXString "`t" 0
  500.         strextract FileSize UDXString "`t" 1
  501.         strextract FileDate UDXString "`t" 2
  502.         strextract FDesc UDXString "`t" 3
  503.         strextract DescBegin UDXString "`t" 4
  504.         strextract DescLength UDXString "`t" 5
  505.         atol DescBegin DB
  506.         atol DescLength DL
  507.         ftell MRunUBFFile NDB
  508.         ;go to the beginning of the file description
  509.         fseek OldUBFFile DB 0
  510.         ;copy the description to the new .UBF file
  511.         for counter = 1 upto DL
  512.             fgetc OldUBFFile char
  513.             fputc MRunUBFFile char
  514.         endfor
  515.         ;add the index line to the new .UDX file
  516.         fstrfmt MRunUDXFile "%s`t%s`t%s`t%s`t%ld`t%ld`r`n" \
  517.             ULFileTrunc FileSize FileDate FDesc NDB DL
  518.         fgets OldUDXFile UDXString
  519.     endwhile
  520.     ;Add any new files found in the uploads directory
  521.     FullFileName = makefullname(UploadDir, "*.*")
  522.     findfirst FullFileName
  523.     while FOUND
  524.         ;Loop through all files in the upload directory
  525.         ULFileTrunc = $FILENAME
  526.         InUDX = checkudx(ULFileTrunc)
  527.         if InUDX == 0
  528.             ULFileFull = makefullname(UploadDir, ULFileTrunc)
  529.             getfsize ULFileFull FS
  530.             getfdate ULFileFull FileDate
  531.             strlwr ULFileTrunc
  532.             fseek MRunUDXFile 0 2
  533.             fstrfmt MRunUDXFile "%s`t%ld`t%s`t`t0`t0`r`n" \
  534.                 ULFileTrunc FS FileDate
  535.         endif
  536.         findnext
  537.     endwhile
  538.     fclose MRunUDXFile
  539.     fclose MRunUBFFile
  540.     fclose OldUDXFile
  541.     fclose OldUBFFile
  542.     delfile OldUDX
  543.     delfile OldUBF
  544.     interfaceon()
  545.     sortidx(MRunUDX, ULSortField)
  546. endproc
  547.  
  548.  
  549. #comment
  550. *********************************************************************
  551. * 
  552. * CHECKUDX()
  553. * 
  554. * Called by insertulfile(), getulfiles()
  555. * 
  556. * Checks whether a given file is already in the UDX List.
  557. * If it is, a value of 1 is returned, if not, the file
  558. * is added to the list and a value of 0 is returned.
  559. * 
  560. *********************************************************************
  561. #endcomment
  562.  
  563. func checkudx : integer
  564. strparm CkFileName
  565. string UDXFile, UDXFileString
  566. integer InUDX
  567.     rewind MRunUDXFile
  568.     InUDX = 0
  569.     fgets MRunUDXFile UDXFileString
  570.     while not feof MRunUDXFile
  571.         strextract UDXFile UDXFileString "`t" 0
  572.         if strcmpi CkFileName UDXFile
  573.             InUDX = 1
  574.             exitwhile
  575.         endif
  576.         fgets MRunUDXFile UDXFileString
  577.     endwhile
  578.     return InUDX
  579. endfunc
  580.  
  581.  
  582. #comment
  583. *********************************************************************
  584. * 
  585. * UPDATEUDX()
  586. * 
  587. * Called by main(), insertulfile()
  588. * 
  589. * Calls openfile(), interfaceon(), interfaceoff(),
  590. * makefullname(), sortidx()
  591. * 
  592. * Updates the Upload directory file description database
  593. * and index files.
  594. * 
  595. *********************************************************************
  596. #endcomment
  597.  
  598. proc updateudx
  599. string FileDate, FileSize, FullFileName
  600. string ULDescString, UDXString, UDXFile
  601. long DescBegin, DescLength, l
  602. integer ULDescLength
  603. integer char
  604.     interfaceoff()
  605.     ;Copy all but the new description to the new UDX file
  606.     copyfile MRunUDX OldUDX
  607.     openfile(OldUDXFile, OldUDX, _READWRITE, _TEXT)
  608.     openfile(MRunUDXFile, MRunUDX, _CREATE, _TEXT)
  609.     fgets OldUDXFile UDXString
  610.     while not feof OldUDXFile
  611.         ;Read lines until the end of file or the current file
  612.         strextract UDXFile UDXString "`t" 0
  613.         if strcmpi UDXFile FileName
  614.             exitwhile
  615.         endif
  616.         fputs MRunUDXFile UDXString
  617.         fgets OldUDXFile UDXString
  618.     endwhile
  619.     ;Get the size and date
  620.     if NULLSTR UDXString
  621.         FullFileName = makefullname(UploadDir, FileName)
  622.         if isfile FullFileName
  623.             getfsize FullFileName l
  624.             ltoa l FileSize
  625.             getfdate FullFileName FileDate
  626.             InULDir = 1
  627.         else
  628.             FileSize = "???"
  629.             FileDate = "??/??/??"
  630.             InULDir = 0
  631.         endif
  632.     else
  633.         strextract FileSize UDXString "`t" 1
  634.         strextract FileDate UDXString "`t" 2
  635.     endif
  636.     ;Discard the old description line
  637.     fgets OldUDXFile UDXString
  638.     FileChoice = UDXString
  639.     while not feof OldUDXFile
  640.         fputs MRunUDXFile UDXString
  641.         fgets OldUDXFile UDXString
  642.     endwhile
  643.     openfile(MRunUBFFile, MRunUBF, _READWRITE, _NORMAL)
  644.     ;go to the end of the description database
  645.     fseek MRunUBFFile 0 2
  646.     ftell MRunUBFFile DescBegin
  647.     DescLength = 0
  648.     ULDescLength = 0
  649.     ULDescString = ""
  650.     
  651.     ;read characters from the description box into the database
  652.     openfile(FileDescFile, FileDesc, _READWRITE, _NORMAL)
  653.     fgetc FileDescFile char
  654.     while not feof FileDescFile
  655.         ;read characters until all have been read
  656.         if ((char >= 0x20) && (char <= 0x7E)) || \
  657.             ((char >= 0xA0) && (char <= 0xFE))
  658.             ;Ignore non-printing characters
  659.             fputc MRunUBFFile char
  660.             if ULDescLength < 46
  661.                 ;No special characters in the index file either
  662.                 strfmt ULDescString "%s%c" ULDescString char
  663.                 ULDescLength++
  664.             endif
  665.             DescLength++
  666.         endif
  667.         fgetc FileDescFile char
  668.     endwhile
  669.     fclose MRunUBFFile
  670.     fclose FileDescFile
  671.     
  672.     ;Strip partial words from end of description
  673.     if ULDescLength == 46
  674.         ULDescLength--
  675.         strpeek ULDescString ULDescLength char
  676.         while char > 32
  677.             strdelete ULDescString ULDescLength 1
  678.             ULDescLength--
  679.             strpeek ULDescString ULDescLength char
  680.         endwhile
  681.     endif
  682.     
  683.     strfmt FileChoice "%s`t%s`t%s`t%s`t%ld`t%ld" \
  684.         FileName FileSize FileDate ULDescString DescBegin DescLength
  685.     fputs MRunUDXFile FileChoice
  686.     fclose OldUDXFile
  687.     fclose MRunUDXFile
  688.     delfile OldUDX
  689.     sortidx(MRunUDX, ULSortField)
  690.     interfaceon()
  691. endproc
  692.  
  693.  
  694. #comment
  695. *********************************************************************
  696. * 
  697. * ULFILEBOX()
  698. * 
  699. * Called by main()
  700. * 
  701. * Draws the Upload Files Dialog Box.
  702. * 
  703. *********************************************************************
  704. #endcomment
  705.  
  706. proc ulfilebox
  707. PermRadio = 2
  708. Conf = "0"
  709. FileName = ""
  710. destroydlg
  711. HelpPage = 10
  712. dialogbox 19 38 324 201 15 "Upload Files" HELPID HelpPage
  713.    text  12 27 56 8 left "Filename"
  714.    text  70 27 40 8 left "Size"
  715.    text  104 27 34 8 left "Date"
  716.    text  142 27 117 8 left "Description"
  717.    flistbox 12 38 300 50 MRunUDX DXFileTabs single FileChoice
  718.    groupbox 12 89 300 17
  719.    radiobutton 26 94 60 11 "Unsorted" ULSortField
  720.    radiobutton 91 94 67 11 "Sort by Name" 
  721.    radiobutton 172 94 61 11 "Sort by Size" 
  722.    radiobutton 241 94 62 11 "Sort by Date" endgroup
  723.    text  13 112 49 8 left "Filename:"
  724.    editbox 12 122 101 12 FileName
  725.    text  129 112 67 8 left "Description:"
  726.    feditbox 129 122 182 50 FileDesc
  727.    text  14 158 78 8 right "U/L to Conference:"
  728.    editbox 96 156 16 12 Conf
  729.    radiobutton 12 178 53 13 "Permanent" PermRadio
  730.    radiobutton 70 178 54 13 "Temporary" endgroup
  731.    pushbutton 130 179 30 14 "&Add" normal default
  732.    pushbutton 168 179 30 14 "&Save" normal
  733.    pushbutton 206 179 30 14 "De&lete" normal
  734.    pushbutton 244 179 30 14 "&Refresh" normal
  735.    pushbutton 282 179 30 14 "&Done" cancel
  736.    text  76 9 80 8 right "Upload File to:"
  737.    combobox 160 7 70 42 BBSList BBSChoice sort
  738.    checkbox 13 140 100 10 "File in uploads directory?" InULDir
  739. enddialog
  740. disable CTRL 70
  741. endproc
  742.  
  743.  
  744.  
  745.